#20080914.05
#Dependencies: gnuplot, ghostscript. Optional: PDF viewer, printer, poster (for large printouts).
#Usage from command line: gnuplot thisfile.gnuplot
#Prints a calibrated parabolic reflector mounting template.
#Make sure the printed calibrated square is actually square to preserve the aspect ratio.
#This was designed more as a learning exercise and not to be the end all template generator.

#This outputs a file called "parabola-reflector.ps". To make a PDF of this file:
#   ps2pdf parabola-reflector.ps
#   or
#   ps2pdf parabola-reflector.ps newoutfile.pdf
#If the desired size is smaller, use the print controls in the PDF viewer to
#scale it down (or modify the variables and use scissors).
#Generally the printouts won't be bigger than half the page. Just fold it over in half
#and carefully cut both at once.

#---Building---

#Parabolas. Cut along the outside of the curve and mount a couple of these to radio
#transparent material for rigidity (thick paper, cardboard, plastic). When cutting
#around the parabola, leave some tabs that are long enough to be secured to the
#rectangular reflector. Also leave some tabs on the other side that can be used as
#support mounts to the other parabola cutouts.

#Rectangular Reflectors (not plotted). Use a foil/metal backed rigid material (paper,
#cardboard, plastic) to make the calibrated reflector rectangle. The metal material
#(foil+glue, foil tape, metal screen) should be long rectangular in shape and should be
#at least a little higher than the antenna being inserted. The ends of the rectangle
#should not go past the edge of the parabola mount.

#Insert the antenna through the focal point '+' mark. Try to keep the holes small enough
#so the antenna remains a snug fit. The hole may need to be reinforced with tape.

#General. For more permanant and stronger, use thick plastic sheets or glue together
#multiple layers of paper, cardboard, fabric, or other fibrous material which creates a
#stronger composite material similar to fiber glass and carbon fiber setups (although
#water based glue and paper products can be a pain). If you want to go into way overkill,
#look into epoxy (but by that point, it's probably better to build a custom directional
#antenna). For the rest of us, gluing and maybe a light paint or polyurethane spray
#coating would be more than enough. Extra thick old manuals, catalogs, or phone books
#with some wax paper is an easy way to hold the parabola mount while drying if it is
#folded over at a specific distance.

#If the reflector material is not a solid metal, make sure the screen holes are
#1/10th lamda or smaller. If you use window screening, make sure it is really metal first.

#3M Super 77 spray glue is the only adhesive that I know of that will reasonably stick to
#aluminum foil. It acts as a kind of slow curing rubber cement. A sheet of paper could be
#glued to each side of the foil and from there regular glue could be used for the rest.

#Keep in mind to not make this entire setup too heavy as it has to sit on a rubber ducky.

#---Program Tweaks---

#The "mymultiplier" variable can be changed to move the focal point back and
#forth and vary the parabolic curve. It is usually less than 1. Larger numbers
#narrow the parabolic curve and move the focal point mathematically closer to
#the vertex.

#The "myxrange" variable can be changed to vary the zoom of the parabola and change
#its apparent shape slightly. It is a multiplier of the vertex to focal point distance.
#Larger numbers show more of the parabolic curve. This has an automatic component
#and may not behave as expected (page size limitations).

#The "myyrange" variable generally isn't used unless making a very narrow parabola.

#---General Design Tips---

#wavelength equation: lambda = c / frequency

#While not always easy on small scale, try to put the focal point at a multiple of
#one wavelength from the parabola's edge for best performance of the driven element (DE).
#This means a rounded/circular type vertex is more preferrable than flat or pointy.

#The wavelength becomes wider at the side of the focal point closest to the reflector
#because of the reflection.

#A deeper dish design tends to be far more directional than a shallow one. It will
#generally have better rejection from side interference. The tradeoff is that the
#signal tends to "pool up in a bowl" and has a very narrow field of focus. The
#parabola along the vertex will need to be very accurate. Think of a low f-stop
#number on a camera lens.

#When viewed straight on from a distance, the larger the apparent surface is,
#the more RF signal that can be collected. If you've played with the variables,
#by now you've noticed that this template was designed for a full length of a sheet
#of paper. Vary the focal point and depth to your design needs.

#Polarization. When a signal hits a reflector, it rotates 90 degrees. If your
#antenna was straight up without the reflector, it should be sideways with it
#(or vice versa).

#============================================================

#If designing narrow reflectors, replace landscape with portrait and swap xrange with yrange.
set terminal postscript landscape enhanced monochrome solid blacktext 8
set output "parabola-reflector.ps"

#manual aspect ratio (annoying old way)
#gnuplot defaults to 5" width and 3.5" height. This messes with the aspect ratio.
#myxrange = 2.5
#myyrange = 3.5
#set size 1,1

#vary this as noted above.
mymultiplier = 0.010

#don't touch this
myfocus = 1/(4*mymultiplier)

#vary this as noted above
myxrange = 2.3
#myyrange = 4
set xrange [(-myxrange*myfocus):(myxrange*myfocus)]
#set yrange [0:(myyrange*myfocus)]
set size ratio -1

#turn off excess that isn't needed.
set nokey
set noxtics
set noytics
set noztics
set border 0

#plot an arrow box as a square aspect ratio reference.
myboxstart = 3
myboxsize = 8
set arrow 1 from myboxstart,myboxstart to myboxstart,(myboxstart+myboxsize) nohead
set arrow 2 from myboxstart,(myboxstart+myboxsize) to (myboxstart+myboxsize),(myboxstart+myboxsize) nohead
set arrow 3 from (myboxstart+myboxsize),(myboxstart+myboxsize) to (myboxstart+myboxsize),myboxstart nohead
set arrow 4 from myboxstart,myboxstart to (myboxstart+myboxsize),myboxstart nohead

#plot the focal point for the antenna insert hole
myplussize = 2
set arrow 5 from 0,(myfocus-myplussize) to 0,(myfocus+myplussize) nohead
set arrow 6 from -myplussize,myfocus to myplussize,myfocus nohead

#plot the axis for easy directional alignment
set arrow 7 from 0,0 to 0,(myfocus-myplussize-1) head filled

#plot the function
plot mymultiplier*(x**2)
quit